Objectives
- To provide practical experience of performing population pharmacokinetic analysis.
- To learn how PREDPP PK models are specified using NM-TRAN.
Introduction
A data set is provided which was simulated using NONMEM. It consists of sparse observations
(4 per subject) in 100 subjects after a single oral dose. The subject weight, age
and sex are recorded.
Note: All files should be loaded from and saved to your Pharmacometrics Data\Population PK folder for this assignment.
- Go to the Pharmacometrics Data\Population PK folder.
- Open the ka1.ctl file.
- Start a NONMEM run using the ka1.ctl NM-TRAN control stream with:
nmgo ka1
- When the run is finished the results will be shown in a table format extracted from
the NONMEM output listing.
- Make a copy of ka1.ctl file so that you can test a lag time model.
copy ka1.ctl ka1L.ctl
- Edit ka1L.ctl as shown in Figure 1.
start notepad ka1L.ctl
$PROBLEM FIRST ORDER
WITH LAG
$INPUT ID TIME AMT WT AGE SEX DV
$DATA tgsparse.dat IGNORE=#
$ESTIM MAXEVAL=9990 POSTHOC NOABORT PRINT=0
$WARN WARN=NONE
$COV
$SUB ADVAN2 TRANS2
$THETA (0,1);popcl
$THETA (0,10);popv
$THETA (0,0.5);popka
$THETA (0,0.5);poptlag
$OMEGA 0.09 ;etacl
$OMEGA 0.09 ;etav
$OMEGA 0.09 ;etaka
$OMEGA 0.09 ;etatlag
$SIGMA 0.01 ;errcv
$SIGMA 0.25 ;errsd
$PK
CL= popcl*EXP(etacl)
V= popv*EXP(etav)
KA= popka*EXP(etaka)
TLAG=poptlag*EXP(etatlag)
ALAG1= TLAG
S2= V
$ERROR
CP=F
Y=CP*EXP(errcv)+errsd
$TABLE ID TIME WT AGE SEX CL V KA Y
ONEHEADER NOPRINT FILE=ka1l.fit
Figure 1. Code for ka1L.ctl.
- Run ka1L.ctl and examine the results.
nmgo ka1L
- Make a copy of the better
model control file so that you can see if sex affects clearance:
copy ka1L.ctl ka1L_sexcl.ctl
- Edit ka1L_sexcl.ctl.
Add a new parameter, FSEX, to make CL in females a fraction
of that in males (Figure 2).
$PROBLEM FIRST ORDER WITH LAG
$INPUT ID TIME AMT WT AGE SEX DV
$DATA tgsparse.dat IGNORE=#
$ESTIM MAXEVAL=9990 POSTHOC NOABORT PRINT=0
$WARN WARN=NONE
$COV
$SUB ADVAN2 TRANS2
$THETA (0,1);popcl
$THETA (0,10);popv
$THETA (0,0.5);popka
$THETA (0,0.5);poptlag
$THETA (0,1,);fsex
$OMEGA 0.09 ;etacl
$OMEGA 0.09 ;etav
$OMEGA 0.09 ;etaka
$OMEGA 0.09 ;etatlag
$SIGMA 0.01 ;errcv
$SIGMA 0.25 ;errsd
$PK
IF (SEX.LT.1) THEN
FSEX=fsex
ELSE
FSEX=1 ; male or missing
ENDIF
CL= FSEX*popcl*EXP(etacl)
V= popv*EXP(etav)
KA= popka*EXP(etaka)
TLAG= poptlag*EXP(etatlag)
ALAG1= TLAG
S2=V
$ERROR
CP=F
Y=CP*EXP(errcv)+errsd
$TABLE ID TIME WT AGE SEX CL V KA Y
ONEHEADER NOPRINT FILE=ka1l.fit
Figure 2. Code for ka1L_sexcl.ctl.
- Run ka1L_sexcl.ctl and examine the results.
- You can compare the results of all your runs so far with the commands:
nmobj Summary of obj values.
nmmbt Model building table. Open
with Excel to examine the results more easily.
- Experiment with changing the model and explore the influence of weight, age, and
sex
on the model parameters.
Assignment
- Describe the models you used to describe the fixed effects of covariates.
- Justify in biological terms the influence of each covariate you found to be important.
- List the objective function values for each model with a brief description of each model.
- Describe how you decide on the best model.
- Provide the code stream for
the best model.
Top
